:GetXYSizeInScreen4x3ScaleBy640x480
:GetXYPosInScreen4x3ScaleBy640x480
{
 Description: 
    Uses 4:3 ratio and 640 x 480 scale and returns XY size according to user screen.
 Type: PROPERTY
 
 Parameters:
   Passed:
     0@ - X size (0.0 to 640.0)
     1@ - Y size (0.0 to 480.0)
   Result:
     none
 
 Example:
  0AB1: call_scm_func @GetXYSizeInScreen4x3ScaleBy640x480 2 XSize 320.0 YSize 240.0 store_XSize 5@ store_YSize 6@
}  
0AB1: call_scm_func @GetCurrentResolution 0 X_size 2@ Y_size 3@
0093: 2@ = integer 2@ to_float
0093: 3@ = integer 3@ to_float

3@ *= 1.33333333    // 4/3
0073: 2@ /= 3@ // (float)
0073: 0@ /= 2@ // (float)

1@ /= 1.07142857        // 480/448
0AB2: ret 2 XSize 0@ YSize 1@

:GetXYSizeInScreenScaleByUserResolution
{
 Description: 
    Uses 4:3 ratio and 640 x 480 scale and returns XY size according to user screen.
 Type: PROPERTY
 
 Parameters:
   Passed:
     0@ - X size
     1@ - Y size
   Result:
     none
 
 Example:
  0AB1: call_scm_func @GetXYSizeInScreenScaleByUserResolution 2 XSizePixels 320.0 YSizePixels 240.0 
}
0AB1: call_scm_func @GetCurrentResolution 0 X_size 2@ Y_size 3@
0093: 2@ = integer 2@ to_float
0093: 3@ = integer 3@ to_float

2@ /= 640.0
0073: 0@ /= 2@ // (float)

3@ /= 448.0
0073: 1@ /= 3@ // (float)
0AB2: ret 2 XSize 0@ YSize 1@

:ConvertGTAXYCoordsInScreenBackTo4x3ScaleBy640x480
{
 Description: 
    Gets XY coordinates in GTA SA scale and using 4:3 ratio and 640 x 480 scale  returns XY size according to user screen.  
 Type: PROPERTY
 
 Parameters:
   Passed:
     0@ - X size (0.0 to 640.0)
     1@ - Y size (0.0 to 448.0)
   Result:
     none
 
 Example:
  0AB1: call_scm_func @ConvertGTAXYCoordsInScreenBackTo4x3ScaleBy640x480 2 X 320.0 Y 224.0 store_X 5@ store_Y 6@
}  
0AB1: call_scm_func @GetCurrentResolution 0 X_size 2@ Y_size 3@
0093: 2@ = integer 2@ to_float
0093: 3@ = integer 3@ to_float

3@ *= 1.33333333    // 4/3
0073: 2@ /= 3@ // (float)
006B: 0@ *= 2@  // (float)

1@ *= 1.07142857        // 480/448
0AB2: ret 2 X 0@ Y 1@